ERC-4907: Rental NFT, EIP-721 的扩展

interface IERC4907 {

    // Logged when the user of an NFT is changed or expires is changed
    /// @notice 当 NFT 的 `user` 更改或 `user` 的 `expires` 更改时发出
    /// 当 user 的地址为零地址时，表示没有 user 地址
    event UpdateUser(uint256 indexed tokenId, address indexed user, uint64 expires);

    /// @notice 设置 NFT 的 user 和 expires
    /// @dev 零地址表示没有 user
    /// 如果 `tokenId` 不是有效的 NFT 则抛出
    /// @param user  NFT 的新 user
    /// @param expires  UNIX 时间戳，新的 user 可以在 expires 之前使用 NFT
    function setUser(uint256 tokenId, address user, uint64 expires) external;

    /// @notice 获取 NFT 的 user 地址
    /// @dev 零地址表示没有 user 或 user 已过期
    /// @param tokenId 要获取 user 地址的 NFT
    /// @return 此 NFT 的 user 地址
    function userOf(uint256 tokenId) external view returns(address);

    /// @notice 获取 NFT 的 user 过期时间
    /// @dev 零值表示没有 user
    /// @param tokenId 要获取 user 过期时间的 NFT
    /// @return 此 NFT 的 user 过期时间
    function userExpires(uint256 tokenId) external view returns(uint256);
}

// SPDX-License-Identifier: CC0-1.0
pragma solidity ^0.8.0;

import "./ERC4907.sol";

contract ERC4907Demo is ERC4907 {

    constructor(string memory name, string memory symbol)
     ERC4907(name,symbol)
     {         
     }

    function mint(uint256 tokenId, address to) public {
        _mint(to, tokenId);
    }

}

// SPDX-License-Identifier: CC0-1.0
pragma solidity ^0.8.0;

import "@openzeppelin/contracts/token/ERC721/ERC721.sol";
import "./IERC4907.sol";

contract ERC4907 is ERC721, IERC4907 {
    struct UserInfo 
    {
        address user;   // address of user role
        uint64 expires; // unix timestamp, user expires
    }

    mapping (uint256  => UserInfo) internal _users;

    constructor(string memory name_, string memory symbol_)
     ERC721(name_, symbol_)
     {
     }
    
    /// @notice set the user and expires of an NFT
    /// @dev The zero address indicates there is no user
    /// Throws if `tokenId` is not valid NFT
    /// @param user  The new user of the NFT
    /// @param expires  UNIX timestamp, The new user could use the NFT before expires
    function setUser(uint256 tokenId, address user, uint64 expires) public virtual{
        require(_isApprovedOrOwner(msg.sender, tokenId), "ERC4907: transfer caller is not owner nor approved");
        UserInfo storage info =  _users[tokenId];
        info.user = user;
        info.expires = expires;
        emit UpdateUser(tokenId, user, expires);
    }

    /// @notice Get the user address of an NFT
    /// @dev The zero address indicates that there is no user or the user is expired
    /// @param tokenId The NFT to get the user address for
    /// @return The user address for this NFT
    function userOf(uint256 tokenId) public view virtual returns(address){
        if( uint256(_users[tokenId].expires) >=  block.timestamp){
            return  _users[tokenId].user;
        }
        else{
            return address(0);
        }
    }

    /// @notice Get the user expires of an NFT
    /// @dev The zero value indicates that there is no user
    /// @param tokenId The NFT to get the user expires for
    /// @return The user expires for this NFT
    function userExpires(uint256 tokenId) public view virtual returns(uint256){
        return _users[tokenId].expires;
    }

    /// @dev See {IERC165-supportsInterface}.
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return interfaceId == type(IERC4907).interfaceId || super.supportsInterface(interfaceId);
    }

    function _beforeTokenTransfer(
        address from,
        address to,
        uint256 tokenId
    ) internal virtual override{
        super._beforeTokenTransfer(from, to, tokenId);

        if (from != to && _users[tokenId].user != address(0)) {
            delete _users[tokenId];
            emit UpdateUser(tokenId, address(0), 0);
        }
    }
}